Arduino countdown LCD display code hour:minute:second format

This is a basic code for countdown display in the format HH:MM: SS; Hour:Minute:Second.

The code uses millis() function of the Arduino to calculate the time, the millis() returns the time in milliseconds passed since the board is ON. It is then used to subtract from the set time value and is converted to a Digital time format.

This code is with a fixed time which has to be initialized with the required values of the hour, minute, and seconds before uploading the sketch. The countdown will always start once the board is ON, if the starting of the countdown needs to be controlled it can be done by an additional input with a simple “if” condition.

Here the code is programmed to display Hour: minute: second as 00:00:00.

Refer: Arduino LCD display interface

Code

#include <LiquidCrystal_I2C.h>
LiquidCrystal_I2C lcd(0x27, 16, 2);
long hour = 23, minute = 59, second = 59;
long countdown_time = (hour*3600) + (minute * 60) + second;
void setup() {
  lcd.init();
  lcd.backlight();
  lcd.setCursor(4, 0);
  lcd.print("HH:MM:SS");
}

void loop() {
  long countdowntime_seconds = countdown_time - (millis() / 1000);
  if (countdowntime_seconds >= 0) {
    long countdown_hour = countdowntime_seconds / 3600;
    long countdown_minute = ((countdowntime_seconds / 60)%60);
    long countdown_sec = countdowntime_seconds % 60;
    lcd.setCursor(4, 1);
    if (countdown_hour < 10) {
      lcd.print("0");
    }
    lcd.print(countdown_hour);
    lcd.print(":");
    if (countdown_minute < 10) {
      lcd.print("0");
    }
    lcd.print(countdown_minute);
    lcd.print(":");
    if (countdown_sec < 10) {
      lcd.print("0");
    }
    lcd.print(countdown_sec);
  }
  delay(500);
}

In the code,  the total time provided in hours, minutes, and seconds are converted to seconds using the formula that obtains the value of the variable “countdown_time”. It is then subtracted with the seconds values obtained from the Arduino function millis() (millis() divided by 1000). Then it is again converted back to hours, minutes, and seconds using the formulas used for variables “countdown_hour”, “countdown_minute, and “countdown_sec” respectively. These values are displayed on the LCD which shows countdown in HH:MM:SS format.

Countdown timer LCD with buzzer

This code is the same as above, the only difference is an additional output to switch ON an LED or buzzer when the countdown reaches Zero.

#include <LiquidCrystal_I2C.h>
LiquidCrystal_I2C lcd(0x27, 16, 2);
long hour = 0, minute = 10, second = 10; long countdown_time = (hour * 3600) + (minute * 60) + second;
int indication = 10; //Connect LED or Buzzer to digital pin 10
void setup() {
  pinMode(indication, OUTPUT);
  lcd.init();
  lcd.backlight();
  lcd.setCursor(4, 0);
  lcd.print("HH:MM:SS");
}

void loop() {
  long countdowntime_seconds = countdown_time - (millis() / 1000);
  if (countdowntime_seconds >= 0) {
    long countdown_hour = countdowntime_seconds / 3600;
    long countdown_minute = ((countdowntime_seconds / 60) % 60);
    long countdown_sec = countdowntime_seconds % 60;
    lcd.setCursor(4, 1);
    if (countdown_hour < 10) {
      lcd.print("0");
    }
    lcd.print(countdown_hour);
    lcd.print(":");
    if (countdown_minute < 10) {
      lcd.print("0");
    }
    lcd.print(countdown_minute);
    lcd.print(":");
    if (countdown_sec < 10) {
      lcd.print("0");
    }
    lcd.print(countdown_sec);
    if (countdowntime_seconds == 0) {
      digitalWrite(indication, HIGH);
    }
  }
  delay(500);
}

LCD countdown display with Keypad input

With the same above countdown method, an additional feature can be added to set the time via the keypad using a 4×4 or 4×3 keypad.

Refer: Arduino 4×4 keypad and LCD display

Code

#include <LiquidCrystal_I2C.h>
LiquidCrystal_I2C lcd(0x27, 16, 2);
#include <Keypad.h>
const byte ROWS = 4;
const byte COLS = 4;
char keys[ROWS][COLS] = {
  {'1', '2', '3', 'A'},
  {'4', '5', '6', 'B'},
  {'7', '8', '9', 'C'},
  {'*', '0', '#', 'D'}
};
byte rowPins[ROWS] = {2, 3, 4, 5};
byte colPins[COLS] = {6, 7, 8, 9};
Keypad keypad = Keypad( makeKeymap(keys), rowPins, colPins, ROWS, COLS );
String action;
long timein[6], countdown_time = 0, initialsecond = 0;
int i = 0;

void setup() {
  lcd.init();
  lcd.backlight();
  lcd.setCursor(4, 0);
  lcd.print("HH:MM:SS");
  lcd.setCursor(4, 1);
  lcd.print("00:00:00");
}

void loop() {
  char key = keypad.getKey();
  if (key) {
    switch (key) {
      //If key is C set time.
      case 'C'  :
        action = "set_time";
        lcd.setCursor(4, 1);
        lcd.blink();
        i = 0;
        break;
      //If key is D start countdown.
      case 'D'  :
        action  = "start_countdown";
        lcd.noBlink();
        break;
      default :
        if (action == "set_time") {
          i++;
          int c = i - 1;
          timein[c] = key - 48;
          initialsecond = 0;
          long hour = (timein[0] * 10) + timein[1];
          long minute = (timein[2] * 10) + timein[3];
          long second = (timein[4] * 10) + timein[5]; //second
          countdown_time = (hour * 3600) + (minute * 60) + second;
          lcd.print(key);
          if (i % 2 == 0 && i < 6) {
            lcd.print(":");
          }
          break;
        }
    }
  }
  if (action  == "start_countdown") {
    if (initialsecond == 0) {
      initialsecond = millis() / 1000;
    }
    long countdowntime_seconds = countdown_time - (millis() / 1000) + initialsecond;
    if (countdowntime_seconds >= 0) {
      long countdown_hour = countdowntime_seconds / 3600;
      long countdown_minute = ((countdowntime_seconds / 60) % 60);
      long countdown_sec = countdowntime_seconds % 60;
      lcd.setCursor(4, 1);
      if (countdown_hour < 10) {
        lcd.print("0");
      }
      lcd.print(countdown_hour);
      lcd.print(":");
      if (countdown_minute < 10) {
        lcd.print("0");
      }
      lcd.print(countdown_minute);
      lcd.print(":");
      if (countdown_sec < 10) {
        lcd.print("0");
      }
      lcd.print(countdown_sec);
    }
    delay(500);
  }
}

Operations to set time and start the countdown.

1. Press “C” to set the time.
2. Then enter time as 6 digit input, for example

For 10minutes 30 seconds enter in HHMMSS -> 001030

For 1 hour 59minutes 59seconds enter in 015959

The code can also modify to add the navigation to the LCD cursor position to select and change the hour, minute, second values separately.

3. Now press D, the countdown begins from the set time.

Once the countdown began, any random button press including the number keys, C or D, D after C nothing interrupt the counting. To change counting the sequence needs to be followed as button C > time input > button D.

The same can be done using a 4×3 keypad by assigning the  * and # buttons as key “C” and “D”.