Servo Motor Control using Arduino Tutorial and Code

The input pulse train at the control signal will turn the rotor to the desired position. The servo motor expects a control pulse at every 20 milliseconds (ms). The width of each pulse directs the servo to turn the shaft to the corresponding angular positions. That is the duration of the positive pulse in a 20ms total pulse width determines the servo shaft position. For a standard servo, 1ms positive pulse maintains a 0° and a maximum of the 2ms positive pulse will have a position of 180°.

Thus the pulse width between 1ms and 2ms obtains a corresponding position between 0° to 180° angles respectively.

How to Connect a Servo motor to Arduino

The servo motors are interfaced with the Arduino through a standard three-wire connection.

Servo motor interfacing with Arduino

Power

The power wire mostly has a red colour, which connects to the 5V pin of the Arduino.

The Servo motor requires a considerable amount of power, especially for high power servos. So, for multiple servos or while using servos along with other pins, it is better to power the servo motor separately with an external supply. Because the power at the remaining pins would be interrupted during its operation.

For external powering, connect the ground of the arduino commonly with the -ve terminal of the external power supply. And connect the supply terminal of the servo (+V) to the  +Ve terminal of the external supply.

Ground

The ground wire typically has black or brown colour. It connects to the ground pin of the Arduino.

Control signal

The signal wire commonly has an orange colour. Yellow, white, blue colours are also used for this connection. One of the Digital pins of Arduino can be used for the signal connection. But, it is commonly used on PWM pins (3, 5, 6, 9, 10, or 11). The servo is mostly connected to pin 9 on the Arduino board. Even the servo is not in use, the analogWrite () (PWM) functionality on pins 9 and 10 disables by the accessing of the library function (except the Arduino Mega). Thus the remaining PWM pins can use for analogwrite () (PWM) by connecting servos to the pin 9 or 10.

Arduino Include Servo Library 

The Arduino Platform itself has the code library for the servo motors. At the beginning of the sketch, the library function needs to be included as, #include <Servo.h>

Servo servo;    create servo object to control a servo.

myservo.attach(9);    attaches the servo on pin 9 to the servo object.

myservo.write(position);          tell servo to go to position in variable ‘position’.

#include <Servo.h> 
 
Servo myservo;                  
int pos = 0;    
 
void setup() 
{ 
  myservo.attach(9);  
} 
 
void loop() 
{ 
  for(pos = 0; pos <= 180; pos += 1) 
  {                                  
    myservo.write(pos);      
    delay(15);                    
  } 
  for(pos = 180; pos>=0; pos-=1)     
  {                                
    myservo.write(pos);              
    delay(15);                     
  } 
} 

Arduino servo motor control with potentiometer

Servo motor position control arduino

#include <Servo.h>

Servo servo1;  
int potin;    

void setup()
{
  servo1.attach(9); 
}

void loop() 
{ 
  potin = analogRead(A0);            
  potin = map(potin, 0, 1023, 0, 180);    
  servo1.write(potin);                  
  delay(15);   
}

Servo motor with LCD Angle Display

In this arrangement, the angles of the servo can be controlled by turning a knob and the current position of the servo will be displayed on the LCD. The servo motor follows the position change in the knob and so we can rotate the servo in clockwise or counterclockwise by rotating the wiper of the potentiometer. The LCD interfaced with Arduino display each present servo position from 0° to 180°.

The circuit works as same as an in the servo knob, the only addition is an LCD interface to read out the position of the servo.

#include <Servo.h>
#include <LiquidCrystal.h>

Servo servo1;  
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);
int potin;    

void setup()
{
  servo1.attach(9); 
  lcd.begin(16, 2);
  lcd.print("position="); 
}

void loop() 
{ 
  potin = analogRead(A0);            
  potin = map(potin, 0, 1023, 0, 180);     
  servo1.write(potin);                  
  delay(15);   
  lcd.setCursor(9, 0);
  lcd.print(potin);
  lcd.print("degree");
}

#include <Servo.h>

Servo servo1;  
int potin,pos;    

void setup()
{
  servo1.attach(9); 
}

void loop() 
{ 
  for(pos = 0; pos <= 180; pos += 1) 
  {     
  potin = analogRead(A0);            
  potin = map(potin, 0, 1023, 0, 1000);    
  servo1.write(pos);                            
  delay(potin); // dealy of 0 to 1000ms               
  } 
  for(pos = 180; pos>=0; pos-=1)     
  {      
  potin = analogRead(A0);            
  potin = map(potin, 0, 1023, 0, 1000);    
  servo1.write(pos);     
  delay(potin);                    
  }                    
}

#include <Servo.h>

Servo servo1;  
long num;     

void setup()
{
 servo1.attach(9);
Serial.begin(9600); 
Serial.print("Enter Position = ");
}

void loop() 
{ 
  while(Serial.available()>0)
  { 
  num= Serial.parseInt();   
  Serial.print(num);  
  Serial.println(" degree");
  Serial.print("Enter Position = ");
  }
  servo1.write(num);
  delay(15);
}

// Code for multiple servo attachment
#include <Servo.h>
Servo servo1;  
Servo servo2; 
long num1,num2;     

void setup()
{
 servo1.attach(9);
 servo2.attach(10);
Serial.begin(9600);
// Separate the values of two positions with a comma.
Serial.println("Enter Position = servo1 degree, servo2 degree ");
Serial.print("Enter Position = ");
}

void loop() 
{ 
  while(Serial.available()>0)
  { 
  num1= Serial.parseInt();   
  Serial.print(num1);  
  Serial.print(" degree , ");
  num2= Serial.parseInt();   
  Serial.print(num2);  
  Serial.println(" degree ");
  Serial.print("Enter Position = ");
  }
  servo1.write(num1);
  servo2.write(num2);
  delay(15);
}

#include <Servo.h>

Servo servo1;  
int num=5,pos;    

void setup()
{
  servo1.attach(9); 
  Serial.begin(9600);
  Serial.print("Enter delay time = ");
}

void loop() 
{ 
  for(pos = 0; pos <= 180; pos++) 
  {     
  while(Serial.available()>0){ 
  num= Serial.parseInt();  
  Serial.print(num);  
  Serial.println(" ms");
  Serial.print("Enter delay time = ");
  } 
  servo1.write(pos); 
  delay(num);
  } 
  for(pos = 180; pos>=0; pos--)     
  {     
  while(Serial.available()>0){ 
  num= Serial.parseInt();  
  Serial.print(num);  
  Serial.println(" ms");
  Serial.print("Enter delay time = ");
  } 
  servo1.write(pos); 
  delay(num);
  }                 
}

#include <Servo.h>

Servo servo1;  
long num, delays;     
int i=0;
void setup()
{
 servo1.attach(9);
Serial.begin(9600); 
Serial.println("Enter Position and delay = position , delay ");
// Separate the values of position and delay by a comma.
Serial.print("Enter Position and delay = ");
}

void loop() 
{ 
  while(Serial.available()>0)
  { 
  num= Serial.parseInt();   
  Serial.print(num);  
  Serial.print(" degree , ");
  delays = Serial.parseInt(); 
  Serial.print(delays);  
  Serial.println(" ms");
  Serial.print("Enter Position and delay = ");
  }
  
  while (i<num){
  i++;
  servo1.write(i);
  delay(delays);
}
 while (i>num){
  i--;
  servo1.write(i);
  delay(delays);
}
i = num;
}

Continuous servo motor

A continuous servo motor or 360° servo has a shaft that rotates continuously. Unlike a standard servo it has no position control but the speed and direction of rotation can be controlled.

The connection of a continuous is same as a standard servo motor, it also has three wires Vcc, GND and signal.

FEETECH FS5106R, Parallax Feedback 360°, SpringRC SM-S4303R are models of continuous servo motors.

Continuous servo motor control

Continuous servo motors are controlled by the pulse width signals between 1000us and 2000us.

For a pulse width of 1000microseconds motor rotates clockwise at maximum speed. When the value increases from 1000us to 1500us the clockwise speed decreases and the motor stops at 1500 microseconds. Further increasing from 1500us the motor speed increases in counterclockwise direction till reaches the maximum speed at 2000us.

Continuous servo motor Arduino code

 #include <Servo.h>

Servo servo;    

void setup()
{
  servo.attach(9); 
}

void loop() 
{
// rotates clockwise at full speed for 3 seconds.
  servo.writeMicroseconds(1000);
  delay(3000);
// rotates clockwise at half speed for 3 seconds.
  servo.writeMicroseconds(1250);
  delay(3000);
// rotation stops for 3s.
  servo.writeMicroseconds(1500);
  delay(3000);
// rotates counter counter clockwise at half speed for 3s.
  servo.writeMicroseconds(1750);
  delay(3000);
// rotates counter counter clockwise at full speed for 3s.
  servo.writeMicroseconds(2000);
  delay(3000);
// rotation stops for 3s.
  servo.writeMicroseconds(1500);
  delay(3000);
}